COMMENT ⊗   VALID 00002 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00002 00002	TITLE DCSTAT
C00004 ENDMK
C⊗;
TITLE DCSTAT

DCHOST==37
DCSOKT==703

DEFINE DCBIN
 PUSHJ 17,NETICW
  JRST 4,.-1
  EXIT
TERMIN

.INSRT NETWRK

DCSTAT:	JFCL
	RESET
	MOVE 17,[PDL(-PDLLEN)]
	MOVEI DCHOST
	MOVEM HOST
	MOVEI DCSOKT
	MOVEM ICPSKT
	PUSHJ 17,CONECT
	 JRST [	PUSHJ 17,MTPERR
		EXIT]
	 JRST [	PUSHJ 17,NIOERR
		EXIT]
	SKIPE FLAGDD
	 JRST QUIT
HEADER:	PUSHJ 17,RENPRE
	CAMN 15,[ASCII/.J900/]
	 EXIT
	CAME 15,[ASCII/.I280/]
	 JRST HEADER
STALIN:	OUTSTR [ASCIZ/] /]
STATUS:	DCBIN
	OUTCHR
	CAIE ↑J
	 JRST STATUS
	DCBIN
	CAIN <" >
	 JRST STALIN
FINISH:	PUSHJ 17,RENLIN
QUIT:	DCBIN
	SKIPE FLAGDD
	 OUTCHR
	JRST QUIT

; RENLIN -- REQUEST END: PROCEED TO NEW LINE
;
RENLIN:	DCBIN
	CAIE ↑J
	 JRST RENLIN
	POPJ 17,

; RENPRE -- REQUEST END: RETURN PREFIX

RENPRE:	SETZ 15,
	MOVE 16,[440700,,15]
RENPRL:	DCBIN
	CAIE ↑M
	 CAIN ↑J
	  JRST RENPRE
	IDPB 16
	TRNN 15,376
	 JRST RENPRL
	LDB [350700,,1]
	CAIN "?
	 JRST [	OUTSTR [ASCIZ/ ?? Fatal Datacomputer error ??/]
		EXIT]
	CAIE "!
	 JRST RENLIN
	OUTSTR [ASCIZ/ (/]
RENLIP:	DCBIN 
	CAIE ↑I
	 JRST RENLIP
	DCBIN
RENLPP:	OUTCHR
	DCBIN
	CAIE 15
	 JRST RENLPP
	DCBIN
	OUTSTR [ASCIZ/)
/]
	POPJ 17,

CONSTA

FLAGDD:	0

PDLLEN==100
PDL:	BLOCK PDLLEN

END DCSTAT